/*
 * Created by PyramIDE.
 * User: Jeremy
 * Date: 04/09/2012
 * Time: 16:19
 * 
 * To change this template use Tools | Options | Coding | Edit Standard Headers.
 */
 
read calexium_lib/web/CXM_making_a_web_site.anubis
read tools/basis.anubis

public type JQuery_tab:
 jQuery_tab(String title, HTML_Off_Form content)
.


define HTML_Partial_Content
  _jquery_tabs
  (
    String              tabs_container_id,
    List(JQuery_tab)    tabs,
    String              tabs_titles,
    List(HTML_Off_Form) tabs_contents,
    Int                 count
  )
  =
   if tabs is
   {
      [ ]         then
        partial_content(
          [],
          sequence([
            literal("<ul>"+tabs_titles+"</ul>"),
            sequence(reverse(tabs_contents))
          ])
        ),
      [ h . t ]   then
        if h is jQuery_tab(title, content) then
          _jquery_tabs(
            tabs_container_id,
            t,
            tabs_titles + "<li><a href=\"#"+tabs_container_id+"-tab-"+count+"\">"+title+"</a></li>",
            [
              sequence([
                literal("<div id=\""+tabs_container_id+"-tab-"+count+"\">"),
                content,
                literal("</div>")
              ])
              .
              tabs_contents
            ],
            count+1
          )
    }
  .
  
  
public define HTML_Partial_Content
  jquery_tabs
  (
    String              tabs_container_id,
    List(JQuery_tab)    tabs
  )
  =
    if _jquery_tabs(tabs_container_id, tabs, "", [], 0) is partial_content(tags, html) then
      partial_content(
        [
          js_inline(script("", "$(document).ready(function(){$('#"+tabs_container_id+"').tabs();});"))
          .
          tags
        ],
        sequence([
          literal("<div id=\""+tabs_container_id+"\">"),
            html,
      	  literal("</div>")
      	])
      )
  .