*Project*                            The Anubis Project
 *Title*                         Producing HTML/Javascript code. 

 *Copyright*                    Copyright (c) Alain Prouté 2001. 
 
read tools/basis.anubis
read system/string.anubis



   *** Managing Web Arguments.

   When a client submits a form, he  sends informations to the server. This information is
   transformed by the server into a list of data of type 'Web_arg'. This is the reason why
   a 'web page' operation always has a unique argument of type 'List(Web_arg)'.

   The type 'Web_arg' is defined in 'web/common.anubis' as follows:
     
         public type Web_arg:
           web_arg(String name, 
                   String value),
           upload (String name, 
                   String value, 
                   String temp_file_path). 

read CXM_common.anubis   
   
   In other words, a  'web argument' is just a pair made of the  name of the argument, and
   the value of  the argument, and both are character strings.  'upload' will be explained
   later.


   The next variable is a multipurpose counter (used to generate unique names). 
   
variable Int web_count = 0.

define Int
  new_web_count 
    =
  web_count <- *web_count+1; 
  *web_count. 
   

   Names for Web colors.
   
public type Web_color_name:
  aliceblue,
  antiquewhite1,
  antiquewhite2,
  antiquewhite3,
  antiquewhite4,
  aquamarine1,
  aquamarine2,
  aquamarine3,
  aquamarine4,
  azure1,
  azure2,
  azure3,
  azure4,
  yellow. 


  and so on ...  (see below why I did not do more).



   Web colors.
   
public type Web_color:
  rgb(Word8,Word8,Word8),    /* give the color by its components */ 
  _(Web_color_name).         /* or by its name */ 


   
   
   The following produces '<meta>' tags, which are put in the head of the document. 
   
public type WebMeta:
  keywords(List(String)), 
  refresh(String url, Int delay),                // in seconds
  meta(String name, String content),
  http_equiv(String name, String content). 
   
   
   
   
   
                *******************************************************
                *                      Web items                      *
                *   (the many kinds of things one may put in a page)  *
                *******************************************************

   
public type Web_item:
  [ ],           /* empty (invisible) item */
  ... this is a cross recursive type. 


   
  
   Options for web page body.
   
public type LayerDisposition:
  horizontal, 
  vertical.
   
public type FollowPathCommand:    // this type is used by the Web_body_option 'follow_path'. 
  pos(Int x,                    // x coordinate of position
      Int y,                    // y coordinate of position
      Int image_number,         // the image to display at that position
      Int delay).               // wait that milliseconds before leaving this position
      
public type Web_body_option:
  background_color(Web_color),               /* color for the background */
   //
   // 'psychedelic_background' produces a background color which is continuously changing.
   // 'average' is the average luminosity of the color. 'amplitude' is the maximal variation 
   // the luminosity around the average. 'delay' is the number of milliseconds between two
   // color changes. For example, you may try 'psychedelic_background(200,50,1000)', which
   // produces a background whose color changes very slowly (this is not tiring) among rather
   // light pastel colors. 
   //
  psychedelic_background(Int average,      /* average light (0 to 255) */
                         Int amplitude,    /* amplitude of variation of light */
                         Int delay),       /* in milliseconds */
  background_image(String file_name),        /* name of image file for the background */
   //
   // 'scrolling_layer' produces a layer above the page which is scrolling continuously either
   // vertically or horizontally. The 'content' is indefinitly repeated. 
   //
  scrolling_layer(LayerDisposition,       
                  Int steps,               /* number of pixels of each move */ 
                  Int margin,              /* measured from left or top in pixels */ 
                  Int delay,               /* milliseconds for one move */
                  Web_item content,          /* content of layer (will be repeated) */ 
                  Int period),             /* number of pixels between two instances of 'content' */ 
   //
   // 'bounce' shows its content above the page and let it move and bounce on the edges of a rectangle.
   // The rectangle is determined by the last 4 arguments. 
   //
  bounce(Web_item content,
         Int left,
         Int right,
         Int top,
         Int bottom),
   //
   // put something over the page in any position you want:
   //
  over(Web_item content, 
       Int left,
       Int top), 
   //
   // follow_path: let a changing image follow a path on the screen. This gadget shows
   //   an image following a polygonal path on the screen. The image may change at regular
   //   intervals, thus providing extra animation. The images are displayed in the order
   //   they are given in the first argument. When the last image has been displayed, the
   //   first image is displayed again, and so on. The path is a sequence of absolute positions
   //   on screen (actually in the browser's window or frame), which is followed in the 
   //   order given in the 'path' argument. If 'loop' is true, the path is followed again and again. 
   //   Otherwise, it is followed only once. If you want to make a closed loop, the last
   //   position must be the same as the first one. 'steps' is the number of pixels of distance
   //   between two successive positions of the image, and 'delay' the number of milliseconds
   //   between two successive positions. 'change_every' is the number of steps (a 'step' is
   //   passing from one position to the next one) after which the displayed image is replaced
   //   by the next image. 
   //
   //   Each position 'pos(x,y,i,d)' has 4 parameters. 'x' and 'y' are the coordinates of the
   //   position in the browser's window or frame. 'i' is the number of the image to display
   //   at this position (i.e. the rank of the image in the list 'filename'. The first one has
   //   rank 0). 'd' is the delay in milliseconds to wait before leaving that position. 
   //
  follow_path(List(String) filenames,     /* the changing images which follows the path */ 
              Int change_every,         /* number of steps betwen two changes */ 
              List(FollowPathCommand) path,       /* the polygonal path and commands */ 
              Bool loop,                  /* if true do it repeatedly, otherwise only once */ 
              Int steps,                /* approximative distance (in pixels) between two 
                                               successive positions */ 
              Int delay),               /* milliseconds between two successive positions */ 
   
  load_image(String name),                /* load an image (for next page), which is not displayed */ 
  left_margin(Int),                     /* left margin for document */ 
  top_margin(Int),                      /* top margin for document */ 
  margin_width(Int), 
  margin_height(Int), 
  reload_frame(String name,       /* name of target frame */
               String url),       /* url to load in this frame */ 
  onload(String function_name).    /* nom de la fonction javascript (sans les '()') */

public type BodyOnload:
  reload_frame(String name, String url). 
   
variable List(BodyOnload) body_onloads = [ ]. 

define One
  add_body_onload
    (
      BodyOnload item
    ) =
  body_onloads <- [item . *body_onloads]. 
   
define Printable_tree
  format
    (
      BodyOnload item
    ) =
  if item is 
    {
      reload_frame(name,url) then (Printable_tree)
        [ " window.open('",url,"','",name,"');" ]
    }.
   
define Printable_tree
  format
    (
      List(BodyOnload) l
    ) =
  if l is 
    {
      [ ] then (Printable_tree)[ ], 
      [h . t] then (Printable_tree)
        [format(h) . format(t)]
    }.
   

---- Body of a web page. --------------------------------------------
public type Page_body:  
  body(List(Web_body_option),   /* list of body options */
       Web_item content).       /* the content of the page */ 


public type VFrame:
 frame(Int height, 
       Printable_tree url,
       String name). 
   
---- Web pages. -----------------------------------------------------
public type Web_page: 
  web_page(String title,             /* title appearing on top of browser */
           List(WebMeta) meta_tags,
           Printable_tree  head_scripts, /* scripts à placer dans la balise head */
           Page_body body),          /* body of page */ 
  standard_frameset(String title,
                    List(WebMeta) meta_tags, 
                    Int height,             /* height of 'top menu' (pixels) */ 
                    Int width,              /* width of 'left menu' (pixels) */ 
                    Printable_tree main).     /* url for main */ 

   +---------+--------------------------+
   |         |                ^         |
   |<-width->|      top     height      |
   |         |                v         |
   | left    +--------------------------+
   |         |                          |
   |         |     main                 |
   |         |                          |
   |         |                          |
   |         |                          |
   +---------+--------------------------+
   
   Note: top and left frames must be loaded through the Web_body_option 'reload_frame'. 
   

public define Web_page
  web_page
    (
      String title, 
      Page_body body
    ) =
  web_page(title,[],[], body). 

public define Web_page
 web_page
   (
    String          title,
    List(WebMeta)   meta_tags,
    Page_body       body
   ) =

 web_page(title, meta_tags, [], body).

 public define Web_page
web_page
  (
   String         title,
   Printable_tree head_scripts,
   Page_body      body
  ) =

  web_page(title, [], head_scripts, body).

public define Web_page
standard_frameset
    (
      String title,
      Int height, 
      Int width,  
      Printable_tree main
    ) =

 standard_frameset(title, [], height, width, main).
   
   
variable Printable_tree scripts = []. 
   
define One
  add_script
    (
      Printable_tree script
    ) =
  scripts <- [*scripts . script]. 
   
   
   
   ---- Non empty web items. -------------------------------------------

   We have already seen the empty web item. Together with the following one, it enables to
   make (pseudo-)lists  of web items,  which will be  presented one after the  other (from
   left to right) in the browser's window.

public type Web_item:
  [Web_item . Web_item],...


   A web item may be a simple string or a simple integer:

public type Web_item:
  text(String),          
  text_pt(Printable_tree), 
  text_nowrap(String),          
  text_nowrap_pt(Printable_tree), 
  par(String),
  preformated_text(String text), 
  integer(Int),
  float(Float,Int),...


   You may want to center a web item in a page. Just enclose it into
   'center(...)': 

public type Web_item:
  center(Web_item),...


   You may want to write characters of a given item with a big font:

public type Web_item:
  bigger(Int,Web_item), 
  smaller(Int,Web_item), 
  bold(Web_item),
  italic(Web_item), 
  big(Web_item),
  very_big(Web_item),...

   
   Most of the previous are subsumed by 'style':
   
public type WebStyle:
  background_image(String file_name),
  background_color(Web_color color), 
  background_transparent, 
  background_repeat_horizontal,    // repeat the background image only horizontally
  background_repeat_vertical,
  background_no_repeat, 
  color(Web_color color), 
  float_to_left,      // the web item will float to the left and text will wrap around 
  float_to_right,
  font_family(String font_name),   // "verdana" "helvetica" "times" etc...
  font_size(Int size), 
  italic,
  oblique,
  small_capitals, 
  bold, 
  bolder,
  lighter,
  line_height(Int height),
  text_center,
  text_left,
  text_right,
  text_justify,
  text_underline,
  text_blink,
  text_line_through,
  width(Int n).
   
  
   
public type Web_item:
  style(List(WebStyle) styles, Web_item content),...
   
   
public type Web_item:
  spacer(Int width, Int height), 
  image(String file_name),              /* image */ 
  image_d(String file_name, String description), 
  image_pt(Printable_tree file_name),
  on_image(String file_name, Web_item content),
  turning_images(NonEmptyList(String) filenames, Int millisecs),...
   
   
   
   A 'rollover' has  the same role as a submit  button or link, but it  is prettier. It is
   made of two images.  The first one  'image_on' determines the aspect of the button when
   the mouse  cursor is on  it.  The  other one 'image_off'  determines the aspect  of the
   button when  the mouse cursor is  anywhere else. The two  images should be  of the same
   size, otherwise bad  effects may occur. The last operand 'description'  is a small text
   which describes the role of the button. It appears in a bubble in the browser's window.
   
public type Web_item:   
  rollover(List(String) preload_images,   // images to preload before the rollover is effective
           String url,                    // URL with possible web arguments
           String target, 
           String image_on,               // file name of 'highlighted' image 
           String image_off,              // file name of 'non highlighted' image
           String description),           // short behavior description
  rollover(List(String) preload_images, 
           String url,    
           String target,        
           String image_on,         
           String image_off,        
           Int width, 
           Int height, 
           String description), ... 
   

   Mouse  sensitive images  are images  with predefined  zones which  are  clickable. When
   clicking in a  zone, the specified corresponding  URL is loaded by the  browser. If two
   zones overlap, the first one (in the order they are defined) is selected.
   
   Zones  are of  3  sorts: rectangles,  circles  and polygons.   Point's coordinates  are
   specified as  pairs of  integers (of anonymous  agglomeration type  (Int,Int)). The
   first coordinate counts pixels from the left of the image. The second coordinate counts
   pixels from  the top of the  image.  With polygons,  you can construct zones  which are
   almost as complicated as you want. You  may also construct a zone as the overlapping of
   several zones with the same URL.
   
public type Mouse_Sensitive_Zone:
  rectangle  
    (   
      (Int,Int) left_top, 
      (Int,Int) right_bottom,
      String url
    ),
  circle     
    (   
      (Int,Int) center,
      Int radius,
      String url
    ),
  polygon
    (   
      List((Int,Int)) vertices,
      String url
    ). 
   
public type Web_item:
  mouse_sensitive_image(String image_file_name,       // the image itself
                        List(Mouse_Sensitive_Zone) zones),...


   In project: mouse  sensitive images, whose zones behave like  submission buttons (to be
   used within a form).
   
   
public type Web_item:
  background_sound(String sound_file_name, 
                   Bool loop),...
   
   

                        *************************
                        *         FORMS         *
                        *************************


   Use 'forms' in  order to get informations back from the  client. The constructor 'form'
   take 2 arguments:

    - the name of the form, which must be the name of an Anubis web
      page. Indeed, when the user will submit the form, this page will
      be sent to him. 
    - the content of the form, which may be any web item, but which
      normally (amongh other things) contains input fields and a
      submit button.  

public type Web_item:
  form(Printable_tree  name,
       Web_item  content),
  form_target(Printable_tree name,
       Web_item content,
       String target),
  form(Printable_tree  name, 
       String label_name,
       Web_item  content),
  form_name(String          form_name,  // option name de form
            Web_item  content),...

 public define Web_item
form
 (
  Printable_tree  name,
  Web_item        content
 ) =

 form("", name, content).

   Within a form, you may put 'text input fields', that the client may
   edit. The constructor 'text_input' has the following arguments: 

    - name of input field. This will be the name of the correponding
      web argument in the Anubis web page referred to by the form. 
    - size of field (as it appears on client screen), 
    - initial value of field (the text that appears in the field, when
      the client downloads the page). 


 public type Text_Input_Option

public type Web_item:
  text_input(String name,           /* text field to be documented by user */
             Int size,
             String initial_value),...

 public define Web_item
 text_input
  (
   String   name,
   Int    size,
   String   initial_value
  ) =


 text_input( (List(Text_Input_Option)) [], name, size, initial_value).


public type Web_item:
  password_input(String name,
                 Int size),
  text_area(String name,
            Int columns, 
            Int rows,
            String initial_text), 
  upload(String name, Int size),...




public type Web_item:
  submit(String button_text),        /* submit button with text on it */
  submit_pt(Printable_tree button_text),
  submit(String name, String text),
  submit_close(String name, String text), 
  submit_pt2(String name, Printable_tree text),
  image_submit(String name, String image_file_name),
  image_submit(String name, String value, String image_file, Web_item content),
  hl_image_submit(String action_name, 
                  String value, 
                  String image_name, 
                  String image_file, 
                  String hl_image_file), 
  text_submit(String name, String value, String text),
  web_submit(String web_args, Web_item content),
  button(String name, String text, String on_click_fonction, Int width, Int height),...


public type Web_item:                         /* mark the form with an information */ 
  mark(String name, String value),
  mark_pt(String name, Printable_tree value),...

public type Web_item:
  close_button,                               /* button that closes the window */ 
  close_button(String image_file_name), ...
   
   
   
                      *********************************
                      *            LABELS             *
                      *********************************
   
   
   A 'label'  is just  a name  that you may  give to  a position in  a document.   Use the
   following invisible  Web_item 'label' to this end.   Now, you can also  create links in
   the same document,  which, when clicked by  the user, scroll the document,  so that the
   position  whose name is  the given  label is  shown just  at the  top of  the browser's
   window.
   
public type Web_item:
  label(String label_name),       /* give a name to a position in the page */ 
  go_to_label(String label_name,  /* a link for jumping to a label */ 
              Web_item content),...



                     ********************************
                     *           TABLES             *
                     ********************************


   A web item may be a table. A table is produced by the constructor
   'table' from the type 'Web_item'. This constructor takes 2
   arguments: 

    - a list of 'table options', 
    - a list of 'table rows'. 

   Of course, you use as many options as you want, including
   none (if you do not want any option, put the empty list '[ ]' as
   this argument). Some options have precedence over others. For example
   a background image will hide the background color. 

   Table options are defined below:

public type Table_option:

      /* use a color as a background for the table, if you want it to
      be different from the background of the page */ 
   background_color(Web_color),   

      /* or use an image as the background of the table */
   background_image(String file_name),

      /* draw a border line around the table (and around each cell in
      the table). You may also specify a geometry (in pixels) for the
      border. This makes the 'in relief' part of the border appear
      more or less wide. You may also specify a color for the border. */
   border,
   nude,           /* equivalent to 'border(0,0,0)' (below) */ 
   border(Int,   /* width of exterior (pixels) */ 
          Int,   /* width of top */
          Int),  /* width of interior */
   border_color(Web_color),
   absolute_width(Int). 



   A 'table row' is made of a list of 'row options', and a list of
   'cells'. A 'cell' itself has a list of 'cell options', and a web item,
   which is its content. We begin by the description of options. 


public type Row_option:
     /* following concerns the horizontal positions of items within the
     cells of the row */
   left,
   h_center,
   right, 
     /* the following concerns the vertical positions of items, within
     the cells of the row */
   top,
   v_center,
   bottom,
   absolute_height(Int), 
   base_line,
     /* set the background color of all cells in the row */ 
   background_color(Web_color).



public type Cell_option:
     /* all row options are available for individual cells, and apply
     here only to one cell. */ 
   left,   
   h_center,
   right, 
   top,
   v_center,
   bottom,
   base_line,
   background_color(Web_color),  
     /* you can set the width of the cell either absolutely (in pixels)
     or as a percentage of the width of the table. */ 
   background_image(String file_name),
   absolute_width(Int),
   relative_width(Int),
   absolute_height(Int),
   relative_height(Int),
     /* a cell may span over several columns or rows in the table */
   columns(Int),
   rows(Int),
   nowrap.


public type Cell:
   cell(List(Cell_option),
        Web_item). 

public type Table_row:
   row(List(Row_option),
       List(Cell)). 
   
public define Table_row row(Web_item i)     = row([],[cell([],i)]). 
public define Table_row row(Cell c)         = row([],[c]). 
public define Table_row row(List(Cell) l)   = row([],l). 
   

public type Web_item:
  table(List(Table_option),
        List(Table_row)),...

public type Web_item: 
  list(List(Web_item)),...

public type Web_item:
  link(String name, Web_item),
  link(String name, String target, Web_item),...

public type Web_item:
  link_for_download(String filename, Web_item),...    // the filename is relative to the public directory
   
public type Web_item:
  mail_to(String addr, Web_item),...


public type Web_item:
  select(String name, 
         Int size, 
         List(String) choices),
  select(String name,
         Int size,
         List(String) choices,
         String selected),
  immediate_select(String name,         // selection will immediately submit the form 
                   Int size,
                   List(String) choices),...


public type Web_item:
  radio_button           (Printable_tree name, String value),
  checked_radio_button   (Printable_tree name, String value),
  check_box              (Printable_tree name, String value),
  checked_box            (Printable_tree name, String value),...


public type Web_item:
  link_to_window(Printable_tree name, Web_item),
  link_to_window(Printable_tree name, String window_name, Web_item),
  link_to_window_with_ticket(String name, 
                             String web_args, 
                             String window_name, 
                             Web_item content,
                             Int width, 
                             Int height), 
  link_to_window_with_ticket_and_scroll
                            (String name, 
                             String web_args, 
                             String window_name, 
                             Web_item content,
                             Int width, 
                             Int height), 
  link_to_window_with_ticket_and_scroll
                            (String name, 
                             String label_name, 
                             String web_args, 
                             String window_name,
                             Web_item content,
                             Int width, 
                             Int height), 
  link_to_frame (Printable_tree name, String frame_name, Web_item). 
  


---- Formating operations (Anubis --> HTML/Javascript) --------------------------- 

   Stupid operation formating a web color name. 

public define String 
  format
    (
      Web_color_name n
    ) =
 if n is
  {
    aliceblue        then   "aliceblue",
    antiquewhite1    then   "antiquewhite1",
    antiquewhite2    then   "antiquewhite2",
    antiquewhite3    then   "antiquewhite3",
    antiquewhite4    then   "antiquewhite4",
    aquamarine1      then   "aquamarine1",
    aquamarine2      then   "aquamarine2",
    aquamarine3      then   "aquamarine3",
    aquamarine4      then   "aquamarine4",
    azure1           then   "azure1",
    azure2           then   "azure2",
    azure3           then   "azure3",
    azure4           then   "azure4",
    yellow           then   "yellow",
  }. 

   Anubis really needs some system of 'macros' to avoid this...


   Formating a web color. 
   
public define String
  format
    (
      Web_color wc
    ) =
  if wc is
    {
      rgb(r,g,b) then "\"#" + to_hexa(r) + to_hexa(g) + to_hexa(b) + "\"",          
      _(c) then format(c) 
    }. 

public define String
  format_without_quotes
    (
      Web_color wc
    ) =
  if wc is
    {
      rgb(r,g,b) then "#" + to_hexa(r) + to_hexa(g) + to_hexa(b) + "",          
      _(c) then format(c) 
    }. 

define Printable_tree
  format
    (
      Web_color c
    ) = [(String)format(c)]. 

public define String
  format_without_sharp
    (
      Web_color wc
    ) =
  if wc is
    {
      rgb(r,g,b) then "" + to_hexa(r) + to_hexa(g) + to_hexa(b) + "",          
      _(c) then format(c) 
    }. 

define Printable_tree
  format_without_sharp
    (
      Web_color c
    ) = [(String)format_without_sharp(c)]. 


define Printable_tree
   [Word32 x . Printable_tree t]
     =
   [to_Int(x) . t].
   
define Printable_tree
  psychedelic_bg
    (
      Int average,
      Int amplitude,
      Int delay
    ) =
  with ampl = if amplitude >= 120 then 120 else 
              if amplitude =< 1 then 1 else amplitude, 
  with aver = if average+ampl >= 254 then 254-ampl 
              else if average-ampl =< 1 then 1+ampl else average,
  [ "<script>",
    " var psy_t = 0;",
    " function do_psy_bg() { psy_t += 0.05;",
    "   document.bgColor = '#' + ",
    "  (Math.round(",aver,"+",ampl,"*Math.cos(psy_t))).toString(16) + ",
    "  (Math.round(",aver,"+",ampl,"*Math.sin(psy_t))).toString(16) + ",
    "  (Math.round(",aver,"-",ampl,"*Math.cos(2*psy_t))).toString(16); ",
    " setTimeout(\"do_psy_bg()\",",delay,"); }",
    " setTimeout(\"do_psy_bg()\",1000);", 
    "</script>"].

   
define List(Web_body_option)
  replace_background_init
    (
      List(Web_body_option) l,
      Int average,
      Int amplitude,
      Int delay
    ) = 
  if l is 
    {
      [ ] then [ ], 
      [h . t] then 
        if h is background_color(_) 
        then [background_color(rgb(truncate_to_Word8(average+amplitude),
                                   truncate_to_Word8(average),
                                   truncate_to_Word8(average-amplitude))) 
              . replace_background_init(t,average,amplitude,delay)]
        else [h . replace_background_init(t,average,amplitude,delay)]
    }.
   
define Maybe((Int,Int,Int))   
  get_psy
    (
      List(Web_body_option) l
    ) = 
  if l is 
    {
      [ ] then failure, 
      [h . t] then 
        if h is psychedelic_background(a,f,d) 
        then success((a,f,d)) 
        else get_psy(t)
    }.
   
define List(Web_body_option)
  prepare
    (
      List(Web_body_option) l
    ) =
  if get_psy(l) is 
    {
      failure then l, 
      success(op) then if op is (a,f,d) then 
        replace_background_init(l,a,f,d)
    }.
   
   
public define Printable_tree
  format
    (
      String c_ticket, 
      String s_ticket,
      Web_item i
    ).   
      
define Printable_tree
  move_layer_command
    (
      String property,
      Int n,
      Int num,
      Int i,
      Int period
    ) =
  if i >= num then [ ] else
  [" if (document.layers)",
   " { document.nslay",n,"_",i,".",property,"=layp",n,"+(",((i-1)),"); } ",
   " else ",
   " { ielay",n,"_",i,".style.",property,"=layp",n,"+(",(i-1)*period,"); } "
   . move_layer_command(property,n,num,i+1,period)].
   
define Printable_tree
  format_layers
    (
      LayerDisposition disp,
      Int margin,
      Web_item content,
      Int n, 
      Int num,
      Int i,
      Int period
    ) =
  if i >= num then [ ] else
  ["<layer name=\"nslay",n,"_",i,"\" top=0",
                           " left=0", ">",
    "<div id=ielay",n,"_",i," style=\"position:absolute;top:",
             if disp is vertical then (i-1)*period else margin,
             "px;left:",
             if disp is vertical then margin else (i-1)*period,
             "px\">",
       format("","",content),
   "</div></layer>" . format_layers(disp,margin,content,n,num,i+1,period)]. 
     
define Printable_tree
  s_layer
    (
      LayerDisposition disp,
      Int steps,
      Int margin,
      Int delay, 
      Web_item content,
      Int period,
      Int num
    ) =
  with n = new_web_count, 
  [ "<script>",
    " var layp",n," = 0;", 
    " function scroll_layer",n,"() {",
    " layp",n,"+=(",steps,"); if (layp",n," ",if steps > 0 then ">" else "<",
             "= ",if steps > 0 then period else 0,
             ")   layp",n," = ",if steps > 0 then 0 else period,";",
    move_layer_command(if disp is vertical then "top" else "left",n,num,0,period),   
    " setTimeout(\"scroll_layer",n,"()\",",delay,");",
    " }",
    " setTimeout(\"scroll_layer",n,"()\",1000);",
    "</script>",
    format_layers(disp,margin,content,n,num,0,period),   
    ].
   
      
define Printable_tree
  over
    (
      Web_item i,
      Int left, 
      Int top
    ) =
  with n = new_web_count, 
  [ "<layer name=\"nslay",n,"\" top=",top," left=",left,">",
    " <div id=\"ielay",n,"\" style=\"position:absolute;top=",top,"px;left=",left,"px\">",
    format("","",i),
    "</div></layer>"
    ]. 
   
define Printable_tree
  bnce
    (
      Web_item i,
      Int left, 
      Int right,
      Int top,
      Int bottom
    ) =
  with n = new_web_count, 
  [ "<script>",
    "  var bncx",n," = ",left,"; var bncy",n," = ",top,"; var bncdx",n," = 1; var bncdy",n," = 1;", 
    " function do_bnc",n,"() {",
    "   if (bncx",n," >= (",right,") || bncx",n," < ",left,") bncdx",n," = -bncdx",n,";", 
    "   if (bncy",n," >= (",bottom,") || bncy",n," < ",top,") bncdy",n," = -bncdy",n,";", 
    "   bncx",n," += bncdx",n,"; bncy",n," += bncdy",n,";", 
    "   if (document.layers)",
    "     { document.nslay",n,".left = bncx",n,"; document.nslay",n,".top = bncy",n,"; } else",
    "     { ielay",n,".style.left = bncx",n,"; ielay",n,".style.top = bncy",n,"; }",
    " setTimeout(\"do_bnc",n,"()\",40); }", 
    " setTimeout(\"do_bnc",n,"()\",1000);",
    "</script>",
    "<layer name=\"nslay",n,"\" top=",top," left=",left,">",
    " <div id=\"ielay",n,"\" style=\"position:absolute;top=",top,"px;left=",left,"px\">",
    format("","",i),
    "</div></layer>"
    ]. 
   
   
define Printable_tree
  folp_switch
    (
      Int n, 
      Int i, 
      List(FollowPathCommand) path, 
      Bool loop,
      Int steps
    ) =
  if path is 
    {
      [ ] then [ ], 
      [p0 . t0] then if p0 is pos(x0,y0,i0,d0) then 
        if t0 is 
          {
            [ ] then if loop
                then ["        default: ",
          "            folpx",n,"=",x0,"; folpy",n,"=",y0,"; ", 
          "            folpseg",n,"=0; ",
          "            folpwait",n,"=",d0,";", 
          "   if(document.layers)",
          "        document.nslay",n,".document.folpim",n,".src=folpimages",n,"[",i0,"].src;", 
          "   else document.folpim",n,".src=folpimages",n,"[",i0,"].src;", 
          "            folpstpmax",n," = 0;",
          "            folpstp",n,"=0;", 
          "            folpdx",n,"=0; ",
          "            folpdy",n,"=0; ",                       
                      "        break;"]
                else ["        default: folpend",n,"=1; break; "], 
            [p1 . t1] then if p1 is pos(x1,y1,i1,d1) then
        [ "          case ",i,": ",
          "            folpx",n,"=",x0,"; folpy",n,"=",y0,"; ", 
          "            folpseg",n,"=",i+1,"; ",
          "            folpwait",n,"=",d0,";", 
          "   if(document.layers)",
          "        document.nslay",n,".document.folpim",n,".src=folpimages",n,"[",i0,"].src;", 
          "   else document.folpim",n,".src=folpimages",n,"[",i0,"].src;", 
          "            folpstpmax",n," = ",
    "Math.round(Math.sqrt(Math.pow(",x1,"-",x0,",2)+Math.pow(",y1,"-",y0,",2))/",steps,");",
          "            folpstp",n,"=0;", 
          "            folpdx",n,"=((",x1,"-",x0,")/folpstpmax",n,"); ",
          "            folpdy",n,"=((",y1,"-",y0,")/folpstpmax",n,"); ", 
          "            break; " 
        . folp_switch(n,i+1,t0,loop,steps) ]
    }}. 
      
define Printable_tree
  set_folpimages
    (
      Int n, 
      List(String) filenames,
      Int i, 
    ) = 
  if filenames is 
    {
      [ ] then [ ], 
      [h . t] then 
        [ " folpimages",n,"[",i,"].src=\"",h,"\";" 
        . set_folpimages(n,t,i+1)]
    }. 
   
define Printable_tree
  follow_path
    (
      List(String) filenames, 
      Int change_every, 
      List(FollowPathCommand) path, 
      Bool loop, 
      Int steps,
      Int delay
    ) =
  if filenames is 
    {
      [ ] then (print("Error in usage of 'follow_path': 'filenames' must be non empty."); []), 
      [im1 . other_ims] then 
  if steps < 1 then (print("Error in usage of 'follow_path': 'step' must be >= 1."); [ ]) else
  if path is 
    {
      [ ] then [ ], 
      [p0 . t0] then if p0 is pos(x0,y0,i0,d0) then 
        if t0 is 
          { 
            [ ] then 
              (print("Error in usage of 'follow_path': 'path' must have at least 2 positions."); []),
            [p1 . t1] then if p1 is pos(x1,y1,i1,d1) then  
        with n = new_web_count, 
       [ 
         "<layer name=\"nslay",n,"\" top=",y0," left=",x0,">",
         "<div id=\"ielay",n,"\" style=\"position:absolute;top=",y0,"px;left=",x0,"px\">",
         "<img src=\"",im1,"\" name=\"folpim",n,"\" border=0>",
         "</div></layer>",
         "<script>",
         "  var folpimages",n,"=new Array(",length(filenames),");", 
         "  var folpcurim",n,"=0;", 
         "  var folpx",n," = ",x0,";", 
         "  var folpy",n," = ",y0,";", 
         "  var folpseg",n," = 1;", 
         "  var folpstpmax",n," = ",
   "Math.round(Math.sqrt(Math.pow(",x1,"-",x0,",2)+Math.pow(",y1,"-",y0,",2))/",steps,");", 
         "  var folpdx",n,"=((",x1,"-",x0,")/folpstpmax",n,"); ",
         "  var folpdy",n,"=((",y1,"-",y0,")/folpstpmax",n,"); ", 
         "  var folpstp",n," = 0;", 
         "  var folpchgcnt",n," = 0;", 
         "  var folpwait",n,"=",d0,";",
         "  var folpend",n,"=0;", 
         "  for(var i = 0; i<",length(filenames),"; i++) {",
         "    folpimages",n,"[i]=new Image(); }", 
         set_folpimages(n,filenames,0), 
         "  function dofolp",n,"() {", 
         "    if (folpstp",n," >= folpstpmax",n,")",
         "      { switch(folpseg",n,") {",
         folp_switch(n,0,path,loop,steps),
         "      }} else { folpstp",n,"++; folpx",n," += folpdx",n,"; folpy",n," += folpdy",n,"; };", 
         "  if (document.layers)",
         "  { document.nslay",n,".left=folpx",n,"; document.nslay",n,".top=folpy",n,"; } else",
         "  { ielay",n,".style.left=folpx",n,"; ielay",n,".style.top=folpy",n,"; };",
   
         //--- change image if needed:
         if change_every = 0 then [ ] else 
         if length(filenames) =< 1 then [ ] else
         ["  if (folpchgcnt",n,"==",change_every,") ",
          "    { ", 
          "      folpchgcnt",n,"=0;",
          "      folpcurim",n,"++;", 
          "      if (folpcurim",n,"==",length(filenames),") folpcurim",n,"=0;", 
          "  if (document.layers) ",
          "       document.nslay",n,".document.folpim",n,".src=folpimages",n,"[folpcurim",n,"].src;",
          "  else document.folpim",n,".src=folpimages",n,"[folpcurim",n,"].src;",
          "    }",
          "    else { folpchgcnt",n,"++; };"],
   
         "  if (!folpend",n,")",
         "    if (folpstp",n,") setTimeout(\"dofolp",n,"()\",",delay,"); ",
         "    else setTimeout(\"dofolp",n,"()\",",delay,"+folpwait",n,"); ",
         "     }",
         "  setTimeout(\"dofolp",n,"()\",1000);", 
         "</script>",
         ]
    }}}. 

   
public type ImageToLoad:
  simple(String image_name),
  with_rollover(String image_name,
                String rollover_name). 
   
variable List(ImageToLoad) images_to_load = [].    
   
public define Printable_tree
  format
    (
      Web_body_option o
    ) =
  if o is
    {
      background_color(c)                then [" bgcolor=" , (String)format(c)],
      psychedelic_background(a,f,d)      then add_script(psychedelic_bg(a,f,d)); [ ], 
      background_image(n)                then [" background=", n],
      scrolling_layer(disp,st,m,t,c,p)   then add_script(s_layer(disp,st,m,t,c,p,2000\p)); [ ], 
      bounce(i,l,r,t,b)                  then add_script(bnce(i,l,r,t,b)); [ ], 
      over(i,l,t)                        then add_script(over(i,l,t)); [ ],
      follow_path(li,ns,p,l,s,d)         then add_script(follow_path(li,ns,p,l,s,d)); [ ], 
      load_image(n)                      then images_to_load <- [simple(n) . *images_to_load]; [ ], 
      left_margin(n)                     then [" leftmargin=", n],
      top_margin(n)                      then [" topmargin=", n],
      margin_width(n)                    then [" marginwidth=", n],
      margin_height(n)                   then [" marginheight=", n],
      reload_frame(n,url)                then add_body_onload(reload_frame(n,url)); [ ],
      onload(n)                          then [" onLoad=\"", n, "()\""] 
    }.

define Printable_tree
  preload_list
    (
      List(ImageToLoad) images,
      Int n, 
    ) =
  if images is 
    {
      [ ] then [ ], 
      [h . t] then 
        ["   preloaded_images[",n,"].src = '",image_name(h),"';",
         if h is 
           {
             simple(_) then [],
             with_rollover(n1,r) then 
               ["   preloaded_images[",n1,"].onload = 'allow_rollover(\"",r,"\")';"]
           }
         . preload_list(t,n-1)]
    }.

define Printable_tree 
  load_image_script
    (
      List(ImageToLoad) images
    ) =
  if images is 
    {
      [ ] then [ ], 
      [_ . _] then 
        [
          "<script>",
          "  var preloaded_images = new Array(",length(images),");", 
          "  var pi_i = 0;", 
          "  for(pi_i = 0; pi_i < ",length(images),"; pi_i++) {", 
          "    preloaded_images[pi_i] = new Image(); }",
          "  function preload_images() {",
          preload_list(images,length(images)-1), 
          "     }</script>"
        ]
    }.

   
public define Printable_tree format(String c_ticket, 
                                    String s_ticket, 
                                    Web_item i). 


public define Printable_tree
 format(List(Table_option) l) =
  if l is 
    {
      [ ] then [ ],
      [h . t] then [if h is 
         {
           background_color(c) then [" bgcolor=", (String)format(c)],
           background_image(f) then [" background=",f],
           border              then [" border"],
           nude                then [" border=\"0\" cellspacing=\"0\" cellpadding=\"0\""],
           border(e,top,i)     then [" border=",e," cellspacing=",top," cellpadding=",i],
           border_color(c)     then [" bordercolor=", (String)format(c)],
           absolute_width(n)   then [" width=",n]
         }, format(t)]
    }. 



public define Printable_tree
  format(List(Row_option) l) =
    if l is
      {
        [ ] then [ ], 
        [first . others] then [if first is
                                 {
                                   left       then [" align=left"],
                                   h_center   then [" align=center"],
                                   right      then [" align=right"],
                                   top        then [" valign=top"],
                                   v_center   then [" valign=center"],
                                   bottom     then [" valign=bottom"],
                           absolute_height(n) then [" height=\"",n,"\""], 
                                   base_line  then [" valign=baseline"],
                                   background_color(c) then [" bgcolor=",(String)format(c)]
                                 },
                               format(others)]
      }.




public define Int
  percentage(Int n) =
         if n < 0 then 0 
    else if n > 100 then 100
    else n. 

 public define Int percentage(Int n) = n. 




public define Printable_tree
  format
    (
      List(Web_body_option) l
    ) =
  if l is 
    {
      [ ] then [ ], 
      [h . t] then [format(h) . format(t)]
    }.  




public define Printable_tree
  format(List(Cell_option) l) =
    if l is
      {
        [ ] then [ ],
        [first . others] then 
          [if first is
             {
               left                then (Printable_tree)[" align=left"],
               h_center            then (Printable_tree)[" align=center"],
               right               then (Printable_tree)[" align=right"],
               top                 then (Printable_tree)[" valign=top"],
               v_center            then (Printable_tree)[" valign=center"],
               bottom              then (Printable_tree)[" valign=bottom"],
               base_line           then (Printable_tree)[" valign=baseline"],
               background_color(c) then (Printable_tree)[" bgcolor=",(String)format(c)],
               background_image(n) then (Printable_tree)[" style=\"background: url(",n,")\""],
               absolute_width(w)   then (Printable_tree)[" width=",w],
               relative_width(r)   then (Printable_tree)[" width=",percentage(r),""],
               absolute_height(h)  then (Printable_tree)[" height=",h],
               relative_height(r)  then (Printable_tree)[" height=",percentage(r),""],
               columns(n)          then (Printable_tree)[" colspan=",n],
               rows(n)             then (Printable_tree)[" rowspan=",n],
               nowrap              then (Printable_tree)[" nowrap"]           
             }
          . format(others)]
      }.



public define Printable_tree
  format
    (
      String c_ticket, 
      String s_ticket, 
      List(Cell) l
    ) =
   if l is
     {
       [ ] then [ ], 
       [first . others] then 
         [if first is cell(options,item) then 
          ["<td",format(options),">",
           format(c_ticket,s_ticket,item),"</td>"],
          format(c_ticket,s_ticket,others)]
     }.


public define Printable_tree
 format
   (
     String c_ticket, 
     String s_ticket, 
     List(Table_row) l
   ) =
  if l is
    {
      [ ] then [ ], 
      [first_row . other_rows] 
        then [if first_row is
                          {
                     row(options,cells) then
                          [ "<tr",format(options),">",
                            format(c_ticket,s_ticket,cells),"</tr>"]
                          },
              format(c_ticket,s_ticket,other_rows)]                    
    }. 


public define Printable_tree
  format_choices
    (
      List(String) l
    ) =
  if l is 
    {
      [ ] then [ ], 
      [h . t] then ["<option>",h . format_choices(t)]
    }.


public define Printable_tree
  format_choices
    (
      List(String) l,
      String selected
    ) =
  if l is 
    {
      [ ] then [ ], 
      [h . t] then if h = selected 
        then ["<option selected>",h . format_choices(t)]
        else ["<option>",h . format_choices(t,selected)]
    }.


public define Printable_tree 
  format_list
    (
      String c_ticket,
      String s_ticket, 
      List(Web_item) l
    ) =
  if l is
    {
      [ ] then [ ],
      [h . t] then ["<li>",format(c_ticket,s_ticket,h),
                           format_list(c_ticket,s_ticket,t)]
    }.

   
public define String
  format
    (
      WebStyle ws
    ) =
  if ws is 
    {
      background_image(fn)          then "background: url("+fn+")",
      background_color(c)           then "background: "+format(c),
      background_transparent        then "background: transparent",
      background_repeat_horizontal  then "background: repeat-x",
      background_repeat_vertical    then "background: repeat-y",
      background_no_repeat          then "background: no-repeat",
      color(wc)                     then if wc is 
                                       {
                                         rgb(r,g,b) then "color: rgb("+r+","+g+","+b+")",
                                         _(c)       then "color: "+format(c)
                                       },
      float_to_left                 then "float: left",
      float_to_right                then "float: right",
      font_family(n)                then "font-family: "+n,
      font_size(n)                  then "font-size: "+to_decimal(n)+"pt",
      italic                        then "font-style: italic",
      oblique                       then "font-style: oblique",
      small_capitals                then "font-variant: small-caps",
      bold                          then "font-weight: bold",
      bolder                        then "font-weight: bolder",
      lighter                       then "font-weight: lighter",
      line_height(h)                then "line-height: "+to_decimal(h),
      text_center                   then "text-align: center",
      text_left                     then "text-align: left",
      text_right                    then "text-align: right",
      text_justify                  then "text-align: justify",
      text_underline                then "text-decoration: underline",
      text_blink                    then "text-decoration: blink",
      text_line_through             then "text-decoration: line-through",
      width(n)                      then "width: "+to_decimal(n),
    }. 
   
   
public define Printable_tree
  format
    (
      List(WebStyle) l
    ) =
  if l is 
    {
      [ ] then [ ], 
      [h . t] then 
        if t is 
          {
            [ ]     then [format(h)], 
            [_ . _] then [format(h), "; " . format(t)]
          }
    }.
   
   
define Printable_tree
  format_polygon_coordinates
    (
      List((Int,Int)) vertices
    ) =
  if vertices is 
    {
      [ ] then [ ],
      [h . t] then  
        if h is (x,y) then 
          if t is [] 
          then [ x,",",y ] 
          else [ x,",",y,"," . format_polygon_coordinates(t)]
    }.
   
 define Printable_tree
  format
    (
      List(Mouse_Sensitive_Zone) zones
    ) =
  if zones is 
    {
      [ ] then [ ], 
      [h . t] then 
        [
          if h is 
           {
             rectangle(lt,rb,url) then 
               if lt is (left,top) then 
               if rb is (right,bottom) then 
                 [ "<area shape=rect coords=\"",left,",",top,",",right,",",bottom,
                          "\" href=\"",url,"\">" ],
             circle(c,r,url) then 
               if c is (x,y) then 
                 [ "<area shape=circle coords=\"",x,",",y,",",r,
                          "\" href=\"",url,"\">" ],
             polygon(vs,url) then 
                 [ "<area shape=poly coords=\"",format_polygon_coordinates(vs),
                          "\" href=\"",url,"\">" ]
           }
        . format(t)]
    }. 

define Printable_tree
  format
    (
      List(Mouse_Sensitive_Zone) zones,
      String                     c_ticket,
      String                     s_ticket,
    ) =
  if zones is 
    {
      [ ] then [ ], 
      [h . t] then 
        [
          if h is 
           {
             rectangle(lt,rb,url) then 
               if lt is (left,top) then 
               if rb is (right,bottom) then 
                 [ "<area shape=rect coords=\"",left,",",top,",",right,",",bottom,
                          "\" href=\"", url + "&c_ticket=" + c_ticket + "&s_ticket=" + s_ticket,"\">" ],
             circle(c,r,url) then 
               if c is (x,y) then 
                 [ "<area shape=circle coords=\"",x,",",y,",",r,
                          "\" href=\"", url + "&c_ticket=" + c_ticket + "&s_ticket=" + s_ticket,"\">" ],
             polygon(vs,url) then 
                 [ "<area shape=poly coords=\"",format_polygon_coordinates(vs),
                          "\" href=\"", url + "&c_ticket=" + c_ticket + "&s_ticket=" + s_ticket,"\">" ]
           }
        . format(t, c_ticket, s_ticket)]
    }. 
   
variable Int map_number = 0. 

define Printable_tree
  format_mouse_sensitive_image
    (
      String image_file_name, 
      List(Mouse_Sensitive_Zone) zones,
      String c_ticket,
      String s_ticket,
    ) =
  map_number <- (*map_number)+1; 
  [
    "<img src=\"",image_file_name,"\" usemap=\"#imsensmap",*map_number,"\" border=0>",
    "<map name=\"imsensmap",*map_number,"\">",
    format(zones, c_ticket, s_ticket),
    "</map>"
  ]. 
   
  
   Find an 'upload' in a web item. 
   
define Bool
  find_upload
    (
      Web_item i
    ). 
   
define Bool
  find_upload
    (
      List(Web_item) li
    ) =
  if li is 
    {
      [ ] then false, 
      [h . t] then if find_upload(h) then true else find_upload(t)
    }. 
   
define Bool
  find_upload
    (
      Cell c
    ) =
  if c is cell(lo,wi) then find_upload(wi). 
   
define Bool
  find_upload
    (
      List(Cell) lc
    ) =
  if lc is 
    {
      [ ] then false, 
      [h . t] then if find_upload(h) then true else find_upload(t)
    }.
   
   
   
define Bool
  find_upload
    (
      Table_row tr
    ) =
  if tr is 
    {
      row(lo,lc) then find_upload(lc)
    }. 
   
define Bool
  find_upload
    (
      List(Table_row) l
    ) =
  if l is 
    {
      [ ] then false, 
      [h . t] then 
        if find_upload(h) then true else find_upload(t)
    }. 
   
define Bool
  find_upload
    (
      Web_item wi
    ) =
  if wi is 
    {
      [ ]                        then (Bool)false, 
      [a . b]                    then (Bool)if find_upload(a) then true else find_upload(b), 
      text(_)                    then (Bool)false, 
      text_pt(_)                 then (Bool)false, 
      text_nowrap(_)             then (Bool)false, 
      text_nowrap_pt(_)          then (Bool)false, 
      par(_)                     then (Bool)false, 
      preformated_text(_)        then (Bool)false,
      integer(_)                 then (Bool)false, 
      float(_,_)                 then (Bool)false, 
      center(i)                  then (Bool)find_upload(i), 
      bigger(n,i)                then (Bool)find_upload(i), 
      smaller(n,i)               then (Bool)find_upload(i), 
      bold(i)                    then (Bool)find_upload(i), 
      italic(i)                  then (Bool)find_upload(i), 
      big(i)                     then (Bool)find_upload(i), 
      very_big(i)                then (Bool)find_upload(i), 
      style(_,i)                 then (Bool)find_upload(i), 
      spacer(_,_)                then (Bool)false,
      image(_)                   then (Bool)false,
      image_d(_,_)               then (Bool)false, 
      image_pt(_)                then (Bool)false, 
      on_image(_,_)              then (Bool)false, 
      turning_images(_,_)        then (Bool)false, 
      rollover(_,_,_,_,_,_)      then (Bool)false, 
      rollover(_,_,_,_,_,_,_,_)  then (Bool)false, 
      mouse_sensitive_image(_,_) then (Bool)false,
      background_sound(_,_)      then (Bool)false, 
      form(_,c)                  then (Bool)find_upload(c), 
      form_target(_,c,_)         then (Bool)find_upload(c), 
      form(_,_,c)                then (Bool)find_upload(c), 
      form_name(_,c)             then (Bool)find_upload(c), 
      text_input(_,_,_)          then (Bool)false,
      password_input(_,_)        then (Bool)false, 
      text_area(_,_,_,_)         then (Bool)false, 
      upload(_,_)                then (Bool)true, 
      submit(_)                  then (Bool)false, 
      submit_pt(_)                  then (Bool)false, 
      submit(_,_)                then (Bool)false, 
      submit_close(_,_)          then (Bool)false, 
      submit_pt2(_,_)                then (Bool)false, 
      image_submit(_,_)          then (Bool)false, 
      image_submit(_,_,_,_)      then (Bool)false, 
      hl_image_submit(_,_,_,_,_) then (Bool)false,
      text_submit(_,_,_)         then (Bool)false, 
      web_submit(_,c)            then (Bool)find_upload(c), 
      button(_,_,_,_,_)          then (Bool)false, 
      mark(_,_)                  then (Bool)false, 
      mark_pt(_,_)               then (Bool)false, 
      close_button               then (Bool)false, 
      close_button(_)            then (Bool)false, 
      label(_)                   then (Bool)false,
      go_to_label(_,i)           then (Bool)find_upload(i), 
      table(_,rows)              then (Bool)find_upload(rows), 
      list(l)                    then (Bool)find_upload(l), 
      link(_,i)                  then (Bool)find_upload(i), 
      link(_,_,i)                then (Bool)find_upload(i), 
      link_for_download(n,i)     then (Bool)find_upload(i), 
      mail_to(_,i)               then (Bool)find_upload(i), 
      select(_,_,_)              then (Bool)false, 
      select(_,_,_,_)            then (Bool)false,
      immediate_select(_,_,_)    then (Bool)false, 
      radio_button(_,_)          then (Bool)false, 
      checked_radio_button(_,_)  then (Bool)false, 
      check_box(_,_)             then (Bool)false, 
      checked_box(_,_)           then (Bool)false, 
      link_to_window(_,i)        then (Bool)find_upload(i), 
      link_to_window(_,_,i)      then (Bool)find_upload(i), 
      link_to_window_with_ticket(_,_,_,i,_,_) then (Bool)find_upload(i), 
      link_to_window_with_ticket_and_scroll(_,_,_,i,_,_) then (Bool)find_upload(i), 
      link_to_window_with_ticket_and_scroll(_,_,_,_,i,_,_) then (Bool)find_upload(i), 
      link_to_frame(_,_,i)       then (Bool)find_upload(i),
    }.
   
   
   The next function generates "enctype=multipart/form-data" or "", depending on the presence of
   an 'upload' in form-content. 
   
define String
  enctype
    (
      Web_item form_content
    ) =
  if find_upload(form_content)
  then "enctype=multipart/form-data"
  else "". 
     
define Printable_tree
  set_turning_images_sources
    (
      Int i, 
      String name, 
      List(String) filenames
    ) =
  if filenames is 
    {
      [ ] then [ ], 
      [h . t] then 
        ["   i",name,"[",i,"].src=\"",h,"\";"
        . set_turning_images_sources(i+1,name,t)]
    }.

define Bool
   member
     (
       Word8 x, 
       Printable_tree t
     ) =
   if t is 
     {
       [] then false, 
       str_pt(String _0,Printable_tree _1) then (member(x,_0) | member(x,_1)), 
       ba_pt(ByteArray _0,Printable_tree _1) then (member(x,to_string(_0)) | member(x,_1)), 
       int_pt(Int _0,Printable_tree _1) then (member(x,to_decimal(_0)) | member(x,_1)), 
       pt_pt(Printable_tree _0,Printable_tree _1) then (member(x,_0) | member(x,_1))
     }. 
    
public define Printable_tree
  format
    (
      String c_ticket, 
      String s_ticket,
      Web_item wi
    ) = 
  if wi is
    {
      [ ]            then (Printable_tree)[ ],

      [a . b]        then (Printable_tree)[format(c_ticket,s_ticket,a), " ", 
                                           format(c_ticket,s_ticket,b)],
   
      text(String s)                then (Printable_tree)[s],
   
      text_pt(Printable_tree s)     then (Printable_tree)s,
   
      text_nowrap(String s)         then (Printable_tree)["<table><tr><td nowrap=\"nowrap>",s,"</td></tr></table>"],
   
      text_nowrap_pt(Printable_tree s) then 
            (Printable_tree)["<table><tr><td \"nowrap\">",s,"</td></tr></table>"],
   
      par(s)                        then (Printable_tree)        
        [ "<p align=\"justify\">", s, " </p>"],
   
      preformated_text(t) then (Printable_tree) ["<pre>",t,"</pre>"],
   
      integer(n)     then (Printable_tree)[n], 
   
      float(f,p)     then (Printable_tree)[float_to_string(f,p)],
   
      center(item)   then (Printable_tree)["<center>", format(c_ticket,s_ticket,item),"</center>"],
   
      bigger(n,item) then (Printable_tree)["<font size=\"+",n,"\">",format(c_ticket,s_ticket,item),"</font>"],
   
      smaller(n,item) then (Printable_tree)["<font size=\"-",n,"\">",format(c_ticket,s_ticket,item),"</font>"],
   
      bold(item)     then 
        (Printable_tree)["<font style=\"font-weight: bold\">",format(c_ticket,s_ticket,item),"</font>"],
   
      italic(item)   then 
        (Printable_tree)["<font style=\"font-style: italic\">",format(c_ticket,s_ticket,item),"</font>"],
   
      big(item)      then (Printable_tree)["<font size=\"+1\">",format(c_ticket,s_ticket,item),"</font>"],
   
      very_big(item) then (Printable_tree)["<h1>",format(c_ticket,s_ticket,item),"</h1>"],
   
      style(l,i)     then 
        (Printable_tree)["<span style=\"", format(l), "\">", format(c_ticket,s_ticket,i), "</span>"],

      spacer(w,h) then (Printable_tree) 
        ["<img src=\"spacer.gif\" width=\"",w,"\" height=\"",h,"\" border=\"0\">"], 
   
      image(String f)               then (Printable_tree)["<img src=\"", f,"\" border=\"0\">"],
   
      image_d(fn,desc) then (Printable_tree)["<img src=\"", fn,"\" alt=\"",desc,"\" border=\"0\">"],
   
      image_pt(Printable_tree l)       then (Printable_tree)["<img src=\"", l,"\" border=\"0\">"],
   
      on_image(fn,x) then (Printable_tree)
        ["<span style=\"background: url(",fn,")\">",format(c_ticket,s_ticket,x),"</span>"],
   
      turning_images(fns,msec) then if fns is [im0 . imo] then 
        with name = "trni"+to_decimal(new_web_count), n = 1+length(imo), (Printable_tree)
        ["<script>",
         "var i",name,"=new Array(",n,");",
         "var n",name,"=0;", 
         "for(var i=0; i<",n,"; i++) {", 
         "  i",name,"[i]=new Image(); }",
         set_turning_images_sources(0,name,(List(String))[im0 . imo]),
   
         "function a",name,"() {", 
         "if (i",name,"[(n",name,"+1)%",n,"].complete)",
         "{n",name,"=(n",name,"+1)%",n,";", 
         "document.",name,".src=i",name,"[n",name,"].src; }",
         "setTimeout(\"a",name,"()\",",msec,"); }",
   
         "setTimeout(\"a",name,"()\",",msec,");", 
         "</script>", 
         "<img src=\"",im0,"\" name=\"",name,"\" border=\"0\">"], 
      
      rollover(prlim,url,target,ion,ioff,descr) then (Printable_tree)
       (images_to_load <- [simple(ion) . *images_to_load]; 
        with name = "ron_"+to_decimal(new_web_count), 
        ["<a target=\"",target,"\" href=\"",url,
        (if (c_ticket = "" & s_ticket = "") then "" else (if member('?',url) then "&" else "?")),
        (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
        (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
         "\" onmouseout=\"",name,".src='",ioff,
         "';\" onmouseover=\"",name,".src='",ion,"';\"><img src=\"",ioff,
         "\" name=\"",name,"\" alt=\"",descr,"\" border=\"0\"></a>"]), 
   
      rollover(prlim,url,target,ion,ioff,w,h,descr) then (Printable_tree)
       (images_to_load <- [simple(ion) . *images_to_load]; 
        with name = "ron_"+to_decimal(new_web_count), 
        ["<a target=\"",target,"\" href=\"",url,
        (if (c_ticket = "" & s_ticket = "") then "" else (if member('?',url) then "&" else "?")),
        (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
        (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
         "\" onmouseout=\"",name,".src='",ioff,
         "';\" onmouseover=\"",name,".src='",ion,"';\"><img src=\"",ioff,
         "\" name=\"",name,"\" width=\"",w,"\" height=\"",h,"\" alt=\"",descr,"\" border=\"0\"></a>"]), 
   
      mouse_sensitive_image(fn,lz) then (Printable_tree)  
               format_mouse_sensitive_image(fn,lz, c_ticket, s_ticket), 
   
      background_sound(sfn,loop) then (Printable_tree)
        ["<embed src=\"", sfn, "\" autostart=\"true\" loop=\"", if loop then "true\">" else "false\">"],
   
      form(n,c)      then (Printable_tree)
        ["<form ",enctype(c)," method=\"post\" action=\"", n, "\">", 
         "<input type=\"hidden\" name=\"s_ticket\" value=\"",s_ticket,"\" />",
         "<input type=\"hidden\" name=\"c_ticket\" value=\"",c_ticket,"\" />",
          format(c_ticket,s_ticket,c),"</form>"],
   
      form_target(n,c,t) then (Printable_tree)
        ["<form ",enctype(c)," method=\"post\" action=\"", n, "\" target=\"", t, "\">", 
         "<input type=\"hidden\" name=\"s_ticket\" value=\"",s_ticket,"\" />",
         "<input type=\"hidden\" name=\"c_ticket\" value=\"",c_ticket,"\" />",
         format(c_ticket,s_ticket,c),"</form>"],
   
      form(n,l,c)    then (Printable_tree)
        ["<form ",enctype(c)," method=\"post\" action=\"", n,"#", l, "\">", 
         "<input type=\"hidden\" name=\"s_ticket\" value=\"",s_ticket,"\" />",
         "<input type=\"hidden\" name=\"c_ticket\" value=\"",c_ticket,"\" />",
         format(c_ticket,s_ticket,c),"</form>"],

      form_name(fn,c)      then (Printable_tree)
        [
         // "<form ",enctype(c), "\" name=\"", fn, "\">", 
          "<form  name=\"", fn, "\">", 
         "<input type=\"hidden\" name=\"s_ticket\" value=\"",s_ticket,"\" />",
         "<input type=\"hidden\" name=\"c_ticket\" value=\"",c_ticket,"\" />",
          format(c_ticket,s_ticket,c),"</form>"],
   
      text_input(n,s,v) then (Printable_tree)
        ["&nbsp; <input type=\"text\" name=\"", n, "\" size=\"", s, "\" value=\"", v,"\" />"],
   
      password_input(n,s) then (Printable_tree)
        ["&nbsp; <input type=\"password\" name=\"", n, "\" size=\"", s,"\" />"],
   
      text_area(name,c,r,i) then (Printable_tree)
        ["<textarea name=\"",name,"\" cols=\"",c,"\" rows=\"",r,"\" wrap=\"physical\">",i,"</textarea>"],
   
      upload(n,size) then (Printable_tree)
       ["<input type=\"file\" size=\"",size,"\" multiple=\"multiple\" name=\"",n,"\" />"],
   
      submit(String t)              then (Printable_tree)["<input type=\"submit\" value=\"",t,"\" />"],
   
      submit_pt(Printable_tree t)      then (Printable_tree)["<input type=\"submit\" value=\"",t,"\" />"],
   
      submit(n, String t)           then (Printable_tree)
        ["<input type=\"submit\" name=\"",n,"\" value=\"",t,"\">"],
 
      submit_close(n, String t) then (Printable_tree)
        ["<input type=\"submit\" name=\"",n,"\" value=\"",t,"\" onclick=\"window.top.close();\" />"],      
   
      submit_pt2(n, Printable_tree t)   then (Printable_tree)
        ["<input type=\"submit\" name=\"",n,"\" value=\"",t,"\" />"],
   
      image_submit(n,ifn) then (Printable_tree)
        ["<input type=\"image\" name=\"",n,"\" src=\"",ifn,"\" border=\"0\" />"],    
   
      image_submit(n,v,ifn,c) then (Printable_tree)
          ["<img src=\"",ifn,"\" onmousedown=\"document.forms[0].action='",
               n,"=",v,"'; document.forms[0].submit();\" />"],
   
      hl_image_submit(n,v,in,ifn,hlifn) then (Printable_tree)
          ["<img src=\"",ifn,"\"",
               //" name=\"",in,"\"",
               " onmouseover=\"this.src='",hlifn,"'\"",
               " onmouseout=\"this.src='",ifn,"'\"",
               " onmousedown=\"document.forms[0].action='",
               n,"=",v,"'; document.forms[0].submit();\" />"],
   
      text_submit(n,v,t)            then (Printable_tree)
          ["<a href=\"",n,
           (if (s_ticket = "" & c_ticket = "" & v = "") then "" else "?"),
           (if s_ticket = "" then [ ] else ["s_ticket=",s_ticket,"&"]),
           (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
           v,"\">",t,"</a>"],


      web_submit(wa,i)             then (Printable_tree)
          ["<a href=\"javascript:document.forms[0].action='",
               wa,"'; document.forms[0].submit();\">",format(c_ticket,s_ticket,i),"</a>"],
   
      button(n, String t, String o, Int w, Int h)  then (Printable_tree)
        ["<input type=button name=",n," value=\"",t,
         "\"style=\"width=",w, ";height=", h, "\" ", "\" onclick=\"", o, "\";\" />"],

      mark(n, String v)             then (Printable_tree)
        ["<input type=\"hidden\" name=\"",n,"\" value=\"",v,"\" />"],
   
      mark_pt(n, Printable_tree v)     then (Printable_tree)
        ["<input type=\"hidden\" name=\"",n,"\" value=\"",v,"\" />"],
   
      close_button     then (Printable_tree)
             ["<form><input type=\"button\" value=\" Fermer \" onclick=\"window.top.close();\"></form>"],

      close_button(ifn)     then (Printable_tree)
             ["<form><input type=\"image\" name=\"close\" src=\"", ifn,
              "\" onclick=\"window.top.close();\" /></form>"],

/*
      close_button(ifn)     then (Printable_tree)
             ["<form><input type=\"button\" name=\"close\" src=\"", ifn,
              "\" onclick=\"window.top.close();\"></form>"],
*/   
      label(name) then (Printable_tree)["<a name=\"",name,"\" />"],
   
      go_to_label(name,content) then (Printable_tree)["<a href=#",name,">",
            format(c_ticket,s_ticket,content),"</a>"], 
   
      table(ops,rows)  then (Printable_tree)["<table ",
                                  format(ops), ">",format(c_ticket,s_ticket,rows),"</table>"],
   
      list(l)   then (Printable_tree)["<ul>",format_list(c_ticket,s_ticket,l),"</ul>"],
   
      link(name,i)    then (Printable_tree)["<a href=\"",name,
        (if (c_ticket = "" & s_ticket = "") then "" else (if member('?',name) then "&" else "?")),
        (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
        (if s_ticket = "" then [ ] else [if c_ticket = "" then "" else "&","s_ticket=",s_ticket]),
        "\">",format(c_ticket,s_ticket,i),"</a>"],
   
      link(name,target,i)    then (Printable_tree)["<a target=\"",target,"\" href=\"",name,
        (if (c_ticket = "" & s_ticket = "") then "" else (if member('?',name) then "&" else "?")),
        (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
        (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
        "\">",format(c_ticket,s_ticket,i),"</a>"],
   
      link_for_download(fname,i) then (Printable_tree)
        ["<a href=\"",fname,"?download\">",format(c_ticket,s_ticket,i),"</a>"],
   
      mail_to(addr,i) then (Printable_tree)["<a href=\"mailto:",addr,"\">",
          format(c_ticket,s_ticket,i),"</a>"],
   
      select(name,size,choices) then (Printable_tree)
         ["<select name=\"",name,"\" size=\"",size,"\">",format_choices(choices),"</select>" ],
   
      select(name,size,choices,selected) then (Printable_tree)
         ["<select name=\"",name,"\" size=\"",size,"\">",format_choices(choices,selected),"</select>" ],
   
      immediate_select(name,size,choices) then (Printable_tree)
         ["<select name=\"",name,"\" size=\"",size,"\" onchange=\"submit();\">",
              format_choices(choices),"</select>" ],
   
      radio_button(n,v)           then (Printable_tree)
        ["<input type=\"radio\" name=\"", n, "\" value=\"", v, "\" />"],
   
      checked_radio_button(n,v)   then (Printable_tree)
        ["<input type=\"radio\" checked=\"checked\" name=\"", n, "\" value=\"", v, "\" />"],
   
      check_box(n,v)              then (Printable_tree)
        ["<input type=\"checkbox\" name=\"", n, "\" value=\"", v, "\" />"],
   
      checked_box(n,v)            then (Printable_tree)
        ["<input type=\"checkbox\" checked=\"checked\" name=\"", n, "\" value=\"", v, "\" />"],
   
      link_to_window(n,i) then (Printable_tree)
        ["<a href=\"javascript:void window.open('",n,"','default','resizable,scrollbars');\">",
            format(c_ticket,s_ticket,i),"</a>"],
   
      link_to_window(n,wn,i) then (Printable_tree)
        ["<a href=\"javascript:void window.open('",n,"','",wn,"','resizable,scrollbars');\" />",
             format(c_ticket,s_ticket,i),"</a>"],
   
      link_to_window_with_ticket(n,args,wn,i,w,h) then (Printable_tree)
        ["<a href=\"javascript:void window.open('",n,"?c_ticket=",c_ticket,
          (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
          "&target=",wn,
          if args="" then "" else "&",
           args,"','",
            wn,"','width=",w,",height=",h,"');\">",
            format(c_ticket,s_ticket,i),"</a>"],

      link_to_window_with_ticket_and_scroll(n,args,wn,i,w,h) then (Printable_tree)
        ["<a href=\"javascript:void window.open('",n,"?c_ticket=",c_ticket,
          (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
          "&target=",wn,
          if args="" then "" else "&",
           args,"','",
            wn,"','width=",w,",height=",h,", resizable,scrollbars');\">",
            format(c_ticket,s_ticket,i),"</a>"],
   
      link_to_window_with_ticket_and_scroll(n,lab,args,wn,i,w,h) then (Printable_tree)
        ["<a href=\"javascript:void window.open('",n,"?c_ticket=",c_ticket,
          (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),
          "&target=",wn,
          if args="" then "" else "&",
           args,"&#",lab, "','",
            wn,"','width=",w,",height=",h,", resizable,scrollbars');\">",
            format(c_ticket,s_ticket,i),"</a>"],
   
      link_to_frame(n,fn,i) then ["<a href=\"",n,
           (if member('?',n) then "&" else "?"),
           (if c_ticket = "" then [ ] else ["c_ticket=",c_ticket]),
           (if s_ticket = "" then [ ] else ["&s_ticket=",s_ticket]),     
           "\" target=\"",fn,"\">",
           format(c_ticket,s_ticket,i),"</a>"]

   }. 


   
define Printable_tree
  add_tickets
    (
      String c_ticket, 
      String s_ticket,
      String url
    ) =
  if member('?',url)
  then [url , "&c_ticket=", c_ticket, "&s_ticket=", s_ticket ]
  else [url , "?c_ticket=", c_ticket, "&s_ticket=", s_ticket ]. 
   
define Printable_tree
  add_tickets
    (
      String c_ticket, 
      String s_ticket,
      Printable_tree url
    ) =
  if member('?',url)
  then [url , "&c_ticket=", c_ticket, "&s_ticket=", s_ticket ]
  else [url , "?c_ticket=", c_ticket, "&s_ticket=", s_ticket ]. 
   
   
define Printable_tree   
  format
    (
      List(VFrame) frames,
      String c_ticket, 
      String s_ticket
    ) =
  if frames is 
    {
      [ ] then [ ], 
      [h . t] then 
        if h is frame(height,url,name) then 
          [
            "<frame src=\"",add_tickets(c_ticket,s_ticket,url), "\" name=\"",name,"\" frameborder=\"no\" />"
          . format(t,c_ticket,s_ticket)]
    }.

   
define String 
  frame_size
    (
      Int s
    ) =
  if s =< 0 then "*" else to_decimal(s). 
   
define String
  frame_stack_rows
    (
      List(VFrame) frames
    ) =
  if frames is 
    {
      [ ] then "", 
      [h . t] then if h is frame (height,url,name) then 
        frame_size(height)+
          if t is 
            {
              [ ] then "", 
              [_ . _] then ","
            }+frame_stack_rows(t)
    }.
   

   
   'crlf' is defined in 'basis.anubis'. 
   
   
   
define Printable_tree
  standard_headers 
    (
      Int size
    ) =
  [
    "HTTP/1.0 200 OK" + crlf +
    "Server: Anubis" + crlf +
    "Content-Type: text/html" + crlf +
    "Content-Length: "+to_decimal(size)+crlf+
    crlf
  ].
   
 define Printable_tree
  download_headers
    =
  [
    "HTTP/1.0 200 OK" + crlf +
    "Content-Type: application/octet-stream" + crlf +
    crlf
  ].
   
define Printable_tree
  apache_headers
    = 
  [
    "Content-type: text/html" + crlf + 
    crlf
  ]. 
   
   
define String
  empty_javascript_source
    =
  "javascript:'<html><head></head><body></body></html>';".
   
public type HeaderSort:
  empty,
  anubis, 
  apache. 

   
define Printable_tree
  format_keywords
    (
      List(String) l
    ) =
  if l is 
    {
      [ ] then [ ], 
      [h . t] then if t is [ ]
        then [h]
        else [h , ", " . format_keywords(t)]
    }. 
   
define Printable_tree
  format
    (
      WebMeta m
    ) =
  if m is 
    {
      keywords(l)        then ["<meta name=\"keywords\" content=\"",format_keywords(l),"\">"],
      refresh(url,delay) then ["<meta http-equiv=\"Refresh\" content=\"",delay,"; URL=",url,"\">"], 
      meta(n,c)          then ["<meta name=\"",n,"\" content=\"",c,"\">"], 
      http_equiv(n,c)    then ["<meta http-equiv=\"",n,"\" content=\"",c,"\">"]
    }.
   
define Printable_tree
  format
    (
      List(WebMeta) metas
    ) =
  if metas is 
    {
      [ ] then [ ],
      [h . t] then [format(h) . format(t)]
    }. 
   
   
   
   
   
   
public define Printable_tree
  format
    (
      HeaderSort hs, 
      String c_ticket, 
      String s_ticket, 
      Web_page p
    ) =
  if p is 
   {
  web_page(title,metas,head_scripts,body) then
    with fullpage =
       [
        "<html>",
        "<head>",
        "<title>", title, "</title>",
        format(metas), 
        head_scripts, 
        "</head>",
        "<body ",
        if body is body(options,item) then 
          with b_options = format(prepare(options)),
           [b_options, " onload='body_onloads();", 
                       if *images_to_load is [] then "" else " preload_images();",
                       "'>", 
            load_image_script(*images_to_load), 
            reverse(*scripts),
            "<script>",
            "  function body_onloads() {",
                 format(*body_onloads),
            "}</script>",
            format(c_ticket,s_ticket,item)
           ],
        "</body>",
        "</html>"
       ],
      [
        if hs is 
           {
              empty then [ ], 
              anubis then standard_headers(length(fullpage)), 
              apache then apache_headers
           } 
        . fullpage
      ],
  standard_frameset(title,metas,height,width,main) then
    with body =
      [
        "<html>",
        "<head>",
        "<title>", title, "</title>",
        format(metas), 
        "</head>",
        "<frameset frameborder=\"no\" border=\"0\" framespacing=\"0\"",
        "    marginwidth=\"0\" marginheight=\"0\" cols=\"",width,",*\" rows=\"*\">",
        "    <frame src=\"",empty_javascript_source,"\" name=\"left\" frameborder=\"no\"",
        "        marginwidth=\"0\" marginheight=\"0\" scrolling=\"no\">",
        "  <frameset frameborder=\"no\" border=\"0\" framespacing=\"0\" rows=\"",height,",*\" cols=\"*\">",
        "    <frame src=\"",empty_javascript_source,"\" name=\"top\"",
                " marginwidth=\"0\" marginheight=\"0\" frameborder=\"no\" scrolling=\"no\">",
        "    <frame src =\"", add_tickets(c_ticket,s_ticket,main), 
              "\" name=\"main\" marginwidth=\"0\" marginheight=\"0\" frameborder=\"no\">",
        "  </frameset>",
        "</frameset>",
        "</html>"
      ],
      [
        if hs is 
           {
              empty then [ ], 
              anubis then standard_headers(length(body)), 
              apache then apache_headers
           }
        . body
      ]
    }.

   
public define Bool
  print
    (
      String c_ticket, 
      String s_ticket, 
      Web_page p
    ) =
  print(format(anubis,c_ticket,s_ticket,p)).    
   
public define Bool
  print_with_headers
    (
      HeaderSort hs,
      String c_ticket, 
      String s_ticket, 
      Web_page p
    ) =
  print(format(hs,c_ticket,s_ticket,p)).    
   
public define Bool
  print
    (
      Web_page p
    ) =
  print(format(anubis,"","",p)). 
   
   
      
   
public define Bool
  print_with_headers
    (
      HeaderSort hs, 
      Web_page p
    ) =
  print(format(hs,"","",p)).
   

public define Cell
  h_spacer
    (
      Int n
    ) =
  cell([absolute_width(n)],text("&nbsp;")). 
   
public define Cell
  v_spacer
    (
      Int n
    ) =
   cell([absolute_height(n)],text("&nbsp;")).
   
public define Cell
  empty = cell([],text("&nbsp;")). 
   

   
   *** Below is a simple gadget for counting visitors. It increments a counter (in a file)
   at each call.  The  argument is the name of the file (relative  to the directory of the
   server), and the file is created automatically. It returns the number of the visitor.

public define Int
  get_visitor_number
    ( 
      String counter_file_name,
    ) =
    protect
    if (RetrieveResult(Int))retrieve(counter_file_name) is
      {
        cannot_find_file  then 
          //
          // It's time to create the file. 
          //
          if save((Int)1,counter_file_name) is 
            {
              cannot_open_file then 0, 
              write_error      then 0, 
              ok               then 1
            },
        read_error    then 0, 
        type_error    then 0, 
        ok(n)         then 
          //
          // Increment the counter
          //
          if save(n+1,counter_file_name) is 
            {
              cannot_open_file then n, 
              write_error      then n, 
              ok               then n+1 
            }
      }.